본문 바로가기

[INTERFACE]/ESP8266

[ESP8266-SSM EVM] 웹서버 테스트

[ESP8266-SSM EVM] ESP8266 웹서버 테스트




ESP8266의 가장 강점은 저렴한 가격의 WiFi 를 구현 할 수 있는것이 아닐까...

우선 가장 간단하게 테스트 해 볼 수 있는 웹서버 예제를 돌려 보자


Arrduino설치시 기본으로 제공하는 웹서버 예제를 다운로드 해서 테스트 해 보았다.

#include <ESP8266WiFi.h>

#include <WiFiClient.h>

#include <ESP8266WebServer.h>

#include <ESP8266mDNS.h>


const char* ssid = "****";

const char* password = "*****";


ESP8266WebServer server(80);


const int led = 13;


void handleRoot() {

  digitalWrite(led, 1);

  server.send(200, "text/plain", "hello from esp8266!");

  digitalWrite(led, 0);

}


void handleNotFound(){

  digitalWrite(led, 1);

  String message = "File Not Found\n\n";

  message += "URI: ";

  message += server.uri();

  message += "\nMethod: ";

  message += (server.method() == HTTP_GET)?"GET":"POST";

  message += "\nArguments: ";

  message += server.args();

  message += "\n";

  for (uint8_t i=0; i<server.args(); i++){

    message += " " + server.argName(i) + ": " + server.arg(i) + "\n";

  }

  server.send(404, "text/plain", message);

  digitalWrite(led, 0);

}


void setup(void){

  pinMode(led, OUTPUT);

  digitalWrite(led, 0);

  Serial.begin(115200);

  WiFi.mode(WIFI_STA);

  WiFi.begin(ssid, password);

  Serial.println("");


  // Wait for connection

  while (WiFi.status() != WL_CONNECTED) {

    delay(500);

    Serial.print(".");

  }

  Serial.println("");

  Serial.print("Connected to ");

  Serial.println(ssid);

  Serial.print("IP address: ");

  Serial.println(WiFi.localIP());


  if (MDNS.begin("esp8266")) {

    Serial.println("MDNS responder started");

  }


  server.on("/", handleRoot);


  server.on("/inline", [](){

    server.send(200, "text/plain", "this works as well");

  });


  server.onNotFound(handleNotFound);


  server.begin();

  Serial.println("HTTP server started");

}


void loop(void){

  server.handleClient();

}




실행하면 접속 정보가 나온다.


Connected to KT_GiGA_DC3E

IP address: 172.30.1.19

MDNS responder started

HTTP server started



그 정보를 이용해서 해당 IP로 접속하면 간단한 웹페이지가 표시되는것을 확인 할 수 있다.







기본 코드는 확인되었으니 이제 좀더 복잡한 웹서버 예제를 돌려 보자


// Load Wi-Fi library

#include <ESP8266WiFi.h>


// Replace with your network credentials

const char* ssid = "****";

const char* password = "****";


// Set web server port number to 80

WiFiServer server(80);


// Variable to store the HTTP request

String header;


// Auxiliar variables to store the current output state

String output5State = "off";

String output4State = "off";


// Assign output variables to GPIO pins

const int output5 = 5;

const int output4 = 16;


void setup() {

  Serial.begin(115200);

  // Initialize the output variables as outputs

  pinMode(output5, OUTPUT);

  pinMode(output4, OUTPUT);

  // Set outputs to LOW

  digitalWrite(output5, LOW);

  digitalWrite(output4, LOW);


  // Connect to Wi-Fi network with SSID and password

  Serial.print("Connecting to ");

  Serial.println(ssid);

  WiFi.begin(ssid, password);

  while (WiFi.status() != WL_CONNECTED) {

    delay(500);

    Serial.print(".");

  }

  // Print local IP address and start web server

  Serial.println("");

  Serial.println("WiFi connected.");

  Serial.println("IP address: ");

  Serial.println(WiFi.localIP());

  server.begin();

}


void loop(){

  WiFiClient client = server.available();   // Listen for incoming clients


  if (client) {                             // If a new client connects,

    Serial.println("New Client.");          // print a message out in the serial port

    String currentLine = "";                // make a String to hold incoming data from the client

    while (client.connected()) {            // loop while the client's connected

      if (client.available()) {             // if there's bytes to read from the client,

        char c = client.read();             // read a byte, then

        Serial.write(c);                    // print it out the serial monitor

        header += c;

        if (c == '\n') {                    // if the byte is a newline character

          // if the current line is blank, you got two newline characters in a row.

          // that's the end of the client HTTP request, so send a response:

          if (currentLine.length() == 0) {

            // HTTP headers always start with a response code (e.g. HTTP/1.1 200 OK)

            // and a content-type so the client knows what's coming, then a blank line:

            client.println("HTTP/1.1 200 OK");

            client.println("Content-type:text/html");

            client.println("Connection: close");

            client.println();

            

            // turns the GPIOs on and off

            if (header.indexOf("GET /13/on") >= 0) {

              Serial.println("GPIO 13 on");

              output5State = "on";

              digitalWrite(output5, HIGH);

            } else if (header.indexOf("GET /13/off") >= 0) {

              Serial.println("GPIO 13 off");

              output5State = "off";

              digitalWrite(output5, LOW);

            } else if (header.indexOf("GET /12/on") >= 0) {

              Serial.println("GPIO 12 on");

              output4State = "on";

              digitalWrite(output4, HIGH);

            } else if (header.indexOf("GET /12/off") >= 0) {

              Serial.println("GPIO 12 off");

              output4State = "off";

              digitalWrite(output4, LOW);

            }

            

            // Display the HTML web page

            client.println("<!DOCTYPE html><html>");

            client.println("<head><meta name=\"viewport\" content=\"width=device-width, initial-scale=1\">");

            client.println("<link rel=\"icon\" href=\"data:,\">");

            // CSS to style the on/off buttons 

            // Feel free to change the background-color and font-size attributes to fit your preferences

            client.println("<style>html { font-family: Helvetica; display: inline-block; margin: 0px auto; text-align: center;}");

            client.println(".button { background-color: #195B6A; border: none; color: white; padding: 16px 40px;");

            client.println("text-decoration: none; font-size: 30px; margin: 2px; cursor: pointer;}");

            client.println(".button2 {background-color: #77878A;}</style></head>");

            

            // Web Page Heading

            client.println("<body><h1>ESP8266 Web Server</h1>");

            client.println("<hr width=\"50%\" color=\"blue\"/>");



            // Display current state, and ON/OFF buttons for GPIO 5  

            client.println("<p>GPIO 13 - State " + output5State + "</p>");

            // If the output5State is off, it displays the ON button       

            if (output5State=="off") {

              client.println("<p><a href=\"/13/on\"><button class=\"button\">ON</button></a></p>");

            } else {

              client.println("<p><a href=\"/13/off\"><button class=\"button button2\">OFF</button></a></p>");

            } 

               

            // Display current state, and ON/OFF buttons for GPIO 4  

            client.println("<p>GPIO 12 - State " + output4State + "</p>");

            // If the output4State is off, it displays the ON button       

            if (output4State=="off") {

              client.println("<p><a href=\"/12/on\"><button class=\"button\">ON</button></a></p>");

            } else {

              client.println("<p><a href=\"/12/off\"><button class=\"button button2\">OFF</button></a></p>");

            }

            client.println("</body></html>");

            

            // The HTTP response ends with another blank line

            client.println();

            // Break out of the while loop

            break;

          } else { // if you got a newline, then clear currentLine

            currentLine = "";

          }

        } else if (c != '\r') {  // if you got anything else but a carriage return character,

          currentLine += c;      // add it to the end of the currentLine

        }

      }

    }

    // Clear the header variable

    header = "";

    // Close the connection

    client.stop();

    Serial.println("Client disconnected.");

    Serial.println("");

  }

}





태그